X,Y,Z,W를 5초동안 rc카가 움직이고 정지하고나서 한 알파벳만 앱으로 보내고 싶은데
계속 보내집니다.
 
1. 블루투스 (A~E)컴맨드 수신에 따른 RC카 구동
2. 5초 기다린 후에
3. RC카 정지
4. 랜덤값 1개만 전송
이렇게 하고 싶다는거죠?
 
// MCU BASIC: https://www.basic4mcu.com
// DateTime : 2018-06-23 오전 8:11:42
// by Ok-Hyun Park
//
#include <SPI.h>
#include "RF24.h"
#include <SoftwareSerial.h>
SoftwareSerial btSerial(2,10);
//
const int IN1=9; //Right Motor(-)
const int IN2=6; //Right Motor(+)
const int IN3=5; //Left Motor(+)
const int IN4=3; //Left Motor(-)
//
int msg[4];
char data=9;
unsigned long pre_time=0,cur_time;
long interval=5000;
RF24 radio(7,8);
const uint64_t pipe=0xE8E8F0F0E1LL;
//
void setup(){
  pinMode(IN1,OUTPUT); pinMode(IN2,OUTPUT); pinMode(IN3,OUTPUT); pinMode(IN4,OUTPUT);
  Serial.begin(19200);
  btSerial.begin(19200);
  radio.begin();
  radio.openReadingPipe(1,pipe);
  radio.startListening();
}
//
void loop(){
  cur_time=millis();
  //
  if(radio.available()){
    radio.read(msg,sizeof(msg));
    if(btSerial.available()){
      data=btSerial.read();
      if(data=='P'){ pre_time=cur_time; btSerial.print('V'); Serial.print("start"); data=0; }
    }
  }
  //
  if(data=='E'){
    if(msg[0]>20&&msg[1]>15&&msg[2]>15&&msg[3]>15){ //forward  다 피면 앞으로
      analogWrite(IN1,150); analogWrite(IN2,0); analogWrite(IN3,150); analogWrite(IN4,0);
      Serial.print("Go"); pre_time=cur_time; data=0;
    }
  }
  if(data=='B'){
    if(msg[0]>20&&msg[1]==0&&msg[2]==0&&msg[3]==0){ //backward 엄지 피면 뒤로
      analogWrite(IN1,0); analogWrite(IN2,150); analogWrite(IN3,0); analogWrite(IN4,150);
      Serial.print("Back"); pre_time=cur_time; data=0;
    }
  }
  if(data=='C'){
    if(msg[0]>25&&msg[1]>20&&msg[2]>20&&msg[3]==0){ //left_엄지 검지 중지 피면 왼쪽
      analogWrite(IN1,0); analogWrite(IN2,80); analogWrite(IN3,80); analogWrite(IN4,0);
      Serial.print("Left"); pre_time=cur_time; data=0;
    }
  }
  if(data=='D'){
    if(msg[0]<5&&msg[1]<5&&msg[2]>25&&msg[3]>25){ //right_중지 약지 피면 오른쪽
      analogWrite(IN1,150); analogWrite(IN2,0); analogWrite(IN3,0); analogWrite(IN4,150);
      Serial.print("Right"); pre_time=cur_time; data=0;
    }
  }
  if(data=='A'){
    if(msg[0]>20&&msg[1]>15&&msg[2]>15&&msg[3]>15){ //forward  다 피면 앞으로
      analogWrite(IN1,150); analogWrite(IN2,0); analogWrite(IN3,150); analogWrite(IN4,0);
      Serial.print("Go"); pre_time=cur_time; data=0;
    }
  }
  //
  if((data==0)&&(cur_time-pre_time>interval)){ pre_time=cur_time;
    analogWrite(IN1,0); analogWrite(IN2,0); analogWrite(IN3,0); analogWrite(IN4,0);
    //
    int value=random(0,4);
    if     (value==0){ btSerial.print('X'); }
    else if(value==1){ btSerial.print('Y'); }
    else if(value==2){ btSerial.print('Z'); }
    else if(value==3){ btSerial.print('W'); }
    data=9;
  }
}
 
char data=9; 
초기값
 data=0; 
RC카 제어 후 0으로 바꿈
    data=9; 
랜덤값 전송 후에는 다시 초기값을 넣어서
랜덤값을 1회만 전송하도록 함